こんにちは。SQL Server サポート チームです。
今回は、Windows 上で動作するSQL Server の異なるインスタンス間で、ログインとパスワードを転送する方法についてご案内します。
SQL Server ではインスタンスに接続する際の認証に使用する（サーバー全体の権限を管理する）ログインという名称のプリンシパルと、インスタンスに接続した後に各データベースに接続する際の認証に使用する（データベースの権限を管理する）ユーザーという名称のプリンシパルが存在します。
本記事ではログインという表記の場合はログインプリンシパルを表し、ユーザーという表記の場合はユーザープリンシパルを意図したものとなります。
一般的にクライアントは、ログインプリンシパルを指定して SQL Server のインスタンスに接続し、ログインプリンシパルとマッピングされたユーザープリンシパルの権限を用いて、データベースにアクセスします。
下記図のようになります。
■概要
Server A で稼働しているインスタンスにあるデータベースを、別の Server B のインスタンスに移行（バックアップリストア/デタッチアタッチなど）すると、以下のようなエラーが発生して、Server B のインスタンスに接続ができない場合があります。
ユーザー ' ログイン名 'の ログインに 失敗しました。 (Microsoft SQL Serverエラー: 18456)
この問題は、Server A の SQL Server のインスタンスに存在していたログインが、Server B の SQL Server のインスタンスに存在しないために発生することがあります。
下記図が問題のイメージです。
また、Server B のインスタンスに Server A と同じ名称のログインを作成して、Server B に移行したデータベースにアクセスしようとしたときに下記のようなエラーが発生して、データベースに接続ができない場合があります。
現在のセキュリティ コンテキストでは、サーバー プリンシパル "<ログイン名>" はデータベース "<データベース名>" にアクセスできません。
この問題は、Server A と Server B でログインの名称が同じでも内部的にログインを識別する SID が異なっていることが原因で発生します。
下記図が問題のイメージです。
本記事では、Server A のインスタンスに存在するログインをパスワードを保ったまま別の Server B のインスタンスにコピーする対応策について紹介します。
■前提条件
・本作業はすべて sysadmin ロールの権限を持ったログインにて実施します。
■手順
1. SQL Server Management Studio（以下、SSMS）やその他のクライアントツールを使って Server A のインスタンスに接続します。
以下スクリプトを実行して、ログインとそのパスワードを転送するのに必要なスクリプトを生成するためのストアドプロシージャを作成します。
USE [master]
GO
IF OBJECT_ID ('sp_hexadecimal') IS NOT NULL
DROP PROCEDURE sp_hexadecimal
GO
CREATE PROCEDURE [dbo].[sp_hexadecimal]
(
@binvalue varbinary(256),
@hexvalue varchar (514) OUTPUT
)
AS
BEGIN
DECLARE @charvalue varchar (514)
DECLARE @i int
DECLARE @length int
DECLARE @hexstring char(16)
SELECT @charvalue = '0x'
SELECT @i = 1
SELECT @length = DATALENGTH (@binvalue)
SELECT @hexstring = '0123456789ABCDEF'
WHILE (@i <= @length)
BEGIN
DECLARE @tempint int
DECLARE @firstint int
DECLARE @secondint int
SELECT @tempint = CONVERT(int, SUBSTRING(@binvalue,@i,1))
SELECT @firstint = FLOOR(@tempint/16)
SELECT @secondint = @tempint - (@firstint*16)
SELECT @charvalue = @charvalue + SUBSTRING(@hexstring, @firstint+1, 1) + SUBSTRING(@hexstring, @secondint+1, 1)
SELECT @i = @i + 1
END
SELECT @hexvalue = @charvalue
END
go
IF OBJECT_ID ('sp_help_revlogin') IS NOT NULL
DROP PROCEDURE sp_help_revlogin
GO
CREATE PROCEDURE [dbo].[sp_help_revlogin]
(
@login_name sysname = NULL
)
AS
BEGIN
DECLARE @name SYSNAME
DECLARE @type VARCHAR (1)
DECLARE @hasaccess INT
DECLARE @denylogin INT
DECLARE @is_disabled INT
DECLARE @PWD_varbinary VARBINARY (256)
DECLARE @PWD_string VARCHAR (514)
DECLARE _varbinary VARBINARY (85)
DECLARE _string VARCHAR (514)
DECLARE @tmpstr VARCHAR (1024)
DECLARE @is_policy_checked VARCHAR (3)
DECLARE @is_expiration_checked VARCHAR (3)
Declare @Prefix VARCHAR(255)
DECLARE @defaultdb SYSNAME
DECLARE @tmpstrRole VARCHAR (1024)
IF (@login_name IS NULL)
BEGIN
DECLARE login_curs CURSOR
FOR
SELECT p.sid, p.name, p.type, p.is_disabled, p.default_database_name, l.hasaccess, l.denylogin
FROM sys.server_principals p
LEFT JOIN sys.syslogins l ON ( l.name = p.name )
WHERE p.type IN ( 'S', 'G', 'U' )
AND p.name <> 'sa'
ORDER BY p.name
END
ELSE
DECLARE login_curs CURSOR
FOR
SELECT p.sid, p.name, p.type, p.is_disabled, p.default_database_name, l.hasaccess, l.denylogin
FROM sys.server_principals p
LEFT JOIN sys.syslogins l ON ( l.name = p.name )
WHERE p.type IN ( 'S', 'G', 'U' )
AND p.name = @login_name
ORDER BY p.name
OPEN login_curs
FETCH NEXT FROM login_curs INTO _varbinary, @name, @type, @is_disabled, @defaultdb, @hasaccess, @denylogin
IF (@@fetch_status = -1)
BEGIN
PRINT 'No login(s) found.'
CLOSE login_curs
DEALLOCATE login_curs
RETURN -1
END
SET @tmpstr = '/* sp_help_revlogin script '
PRINT @tmpstr
SET @tmpstr = '** Generated ' + CONVERT (varchar, GETDATE()) + ' on ' + @@SERVERNAME + ' */'
PRINT @tmpstr
PRINT ''
WHILE (@@fetch_status <> -1)
BEGIN
IF (@@fetch_status <> -2)
BEGIN
PRINT ''
SET @tmpstr = '-- Login: ' + @name
PRINT @tmpstr
SET @tmpstr='IF NOT EXISTS (SELECT * FROM sys.server_principals WHERE name = N'''+@name+''')
BEGIN'
Print @tmpstr
IF (@type IN ( 'G', 'U'))
BEGIN -- NT authenticated account/group
SET @tmpstr = 'CREATE LOGIN ' + QUOTENAME( @name ) + ' FROM WINDOWS WITH DEFAULT_DATABASE = [' + @defaultdb + ']'
END
ELSE
BEGIN -- SQL Server authentication
-- obtain password and sid
SET @PWD_varbinary = CAST( LOGINPROPERTY( @name, 'PasswordHash' ) AS varbinary (256) )
EXEC sp_hexadecimal @PWD_varbinary, @PWD_string OUT
EXEC sp_hexadecimal _varbinary,@SID_string OUT
-- obtain password policy state
SELECT @is_policy_checked = CASE is_policy_checked WHEN 1 THEN 'ON' WHEN 0 THEN 'OFF' ELSE NULL END
FROM sys.sql_logins
WHERE name = @name
SELECT @is_expiration_checked = CASE is_expiration_checked WHEN 1 THEN 'ON' WHEN 0 THEN 'OFF' ELSE NULL END
FROM sys.sql_logins
WHERE name = @name
SET @tmpstr = 'CREATE LOGIN ' + QUOTENAME( @name ) + ' WITH PASSWORD = ' + @PWD_string + ' HASHED, SID = '
+ _string + ', DEFAULT_DATABASE = [' + @defaultdb + ']'
IF ( @is_policy_checked IS NOT NULL )
BEGIN
SET @tmpstr = @tmpstr + ', CHECK_POLICY = ' + @is_policy_checked
END
IF ( @is_expiration_checked IS NOT NULL )
BEGIN
SET @tmpstr = @tmpstr + ', CHECK_EXPIRATION = ' + @is_expiration_checked
END
END
IF (@denylogin = 1)
BEGIN -- login is denied access
SET @tmpstr = @tmpstr + '; DENY CONNECT SQL TO ' + QUOTENAME( @name )
END
ELSE IF (@hasaccess = 0)
BEGIN -- login exists but does not have access
SET @tmpstr = @tmpstr + '; REVOKE CONNECT SQL TO ' + QUOTENAME( @name )
END
IF (@is_disabled = 1)
BEGIN -- login is disabled
SET @tmpstr = @tmpstr + '; ALTER LOGIN ' + QUOTENAME( @name ) + ' DISABLE'
END
Set @Prefix = '
exec master.dbo.sp_addsrvrolemember @loginame='''
Set @tmpstrRole=''
Select @tmpstrRole = @tmpstrRole
+ Case When sysadmin = 1 Then @Prefix + [LoginName] + ''', @rolename=''sysadmin''' Else '' End
+ Case When securityadmin = 1 Then @Prefix + [LoginName] + ''', @rolename=''securityadmin''' Else '' End
+ Case When serveradmin = 1 Then @Prefix + [LoginName] + ''', @rolename=''serveradmin''' Else '' End
+ Case When setupadmin = 1 Then @Prefix + [LoginName] + ''', @rolename=''setupadmin''' Else '' End
+ Case When processadmin = 1 Then @Prefix + [LoginName] + ''', @rolename=''processadmin''' Else '' End
+ Case When diskadmin = 1 Then @Prefix + [LoginName] + ''', @rolename=''diskadmin''' Else '' End
+ Case When dbcreator = 1 Then @Prefix + [LoginName] + ''', @rolename=''dbcreator''' Else '' End
+ Case When bulkadmin = 1 Then @Prefix + [LoginName] + ''', @rolename=''bulkadmin''' Else '' End
From (
select convert(varchar(100),suser_sname(sid)) as [LoginName],
sysadmin,
securityadmin,
serveradmin,
setupadmin,
processadmin,
diskadmin,
dbcreator,
bulkadmin
from sys.syslogins
where ( sysadmin<>0
or securityadmin<>0
or serveradmin<>0
or setupadmin <>0
or processadmin <>0
or diskadmin<>0
or dbcreator<>0
or bulkadmin<>0
)
and name=@name
) L
PRINT @tmpstr
Print @tmpstrRole
Print 'END'
END
FETCH NEXT FROM login_curs INTO _varbinary, @name, @type, @is_disabled, @defaultdb, @hasaccess, @denylogin
END
CLOSE login_curs
DEALLOCATE login_curs
RETURN 0
END
2. 下記のステートメントを実行して、マスターデータベースに2つのストアドプロシージャ sp_hexadecimal と sp_help_revlogin が作成されたことを確認します。
name 列がそれぞれのストアドプロシージャになっている行が出力されていれば、作成されていると判断できます。
USE [master]
GO
SELECT * FROM sys.procedures WHERE name IN ('sp_hexadecimal','sp_help_revlogin')
GO
3. SSMS のクエリ エディタを一度選択した状態で、SSMS のメニューバーから [クエリ] -> [結果の出力] -> [結果をテキストで表示] オプションを選択します。
4. [結果をテキストで表示] 設定を行ったクエリ エディタ―で下記のステートメントを実行します。
EXEC sp_help_revlogin
5. sp_help_revlogin ストアドプロシージャを実行することで、ログインを作成するためのスクリプトが出力されます。
IF NOT ~ END までが一つの塊となるため、Server B にコピーしたいログインに関するスクリプトを抜粋します。
なお、このスクリプトで作成した SQL Server 認証のログインは、元の SID と元のパスワードを保持したものが作成されます。
・ SQL Server 認証のログイン（ sqlUser01）の例
-- Login: sqlUser01
IF NOT EXISTS (SELECT * FROM sys.server_principals WHERE name = N'sqlUser01')
BEGIN
CREATE LOGIN [sqlUser01] WITH PASSWORD = <暗号化されたパスワード> HASHED, SID = <ハッシュ>, DEFAULT_DATABASE = [master], CHECK_POLICY = ON, CHECK_EXPIRATION = ON
END
・Windows 認証のログイン（ <ドメイン名>\winUser01）の例
-- Login: <ドメイン名>\winUser01
IF NOT EXISTS (SELECT * FROM sys.server_principals WHERE name = N'<ドメイン名>\winUser01')
BEGIN
CREATE LOGIN [<ドメイン名>\winUser01] FROM WINDOWS WITH DEFAULT_DATABASE = [master]
END
6. 移行先のサーバー（Server B）での手順
SSMSなどのクライアントツールを使って Server B に接続し、手順5. で抜粋したスクリプト（sp_helprevloginの出力結果）をクエリとして実行します。
■注意事項
手順6 で移行先のサーバー（Server B）での手順を実行する前に、以下の情報を確認してください。
- Server A とServer B が異なるドメインにある場合で、 Windows 認証のログインをコピーする場合は、出力スクリプトを変更する必要があります。
手順5 で抜粋した CREATE LOGIN ステートメントには元のドメイン名が記載されているため、新しいドメイン名を使って置き換える必要があります。
新しいドメインでアクセスを許可された統合ログインは、元のドメインのログインと同じSIDを持たないため、ユーザーはこれらのログインから孤立した状態となります。
これらの孤立したユーザーを解決する方法の詳細については、「SQL Serverを実行しているサーバー間でデータベースを移動するときの権限の問題を解決する方法」を参照してください。
Server A とServer B が同じドメイン内にある場合は、同じ SID が使用されますので、ユーザーが孤立することは通常ありません。
- この記事の手順では、特定のログインに対するデフォルトのデータベース情報の転送はされません。
これは、デフォルト データベースが Server B に存在するとは限らないためです。
- 送信元サーバーと送信先サーバーの照合順序の違いによる注意点：
- 大文字小文字を区別しない Server A と大文字小文字を区別する Server B：
Server A の照合順序が大文字小文字を区別せず、Server B の照合順序が大文字小文字を区別する場合があります。
この場合、Server B のインスタンスにログイン名とパスワードを転送した後、ユーザーはパスワードをすべて大文字で入力する必要があります。 - 大文字小文字を区別する Server A と大文字小文字を区別しない Server B：
Server A の照合順序が大文字小文字を区別し、Server B の照合順序が大文字小文字を区別しない場合があります。
この場合、以下のいずれかの条件が成立しない限り、ユーザーは Server B のインスタンスに転送したログイン名とパスワードを使ってログインすることができません。
・元のパスワードのすべての文字が大文字である。
・元のパスワードに文字が含まれていない。 - 両方のサーバーで大文字と小文字が区別されている、または大文字と小文字が区別されていない:
Server A とServer B の両方のソート順が大文字と小文字を区別している場合や、Server A と Server B の両方のソート順が大文字と小文字を区別していない場合があります。
これらの場合、ユーザーには問題が発生しません。
- 大文字小文字を区別しない Server A と大文字小文字を区別する Server B：
- Server B 上のインスタンスで出力スクリプトを実行した際に以下のようなエラーメッセージが表示された場合：
Msg 15433、レベル 16、状態 1、Line 1 の指定されたパラメーター sid が使用されています。
→Server B 上のインスタンスに出力スクリプト内の名前と同じ名前を持つログインがすでに存在する。
Msg 15025、レベル 16、状態 1、行 1
サーバー プリンシパル 'MyLogin' は既に存在します。
→Server B 上のインスタンスに出力スクリプトの SID と同じ SID を持つログインがすでに存在する。
上記エラーを回避するために、次の操作を行う必要があります。
1. 出力スクリプト内のログイン情報を確認します。
2. Server B 上のインスタンスの sys.server_principals ビューの内容を調べます。
3. 必要に応じて、これらのエラー メッセージに対処します。
本記事は、インスタンス間でログインとパスワードを転送する - SQL Server | Microsoft Docs の情報を一部補足した内容となっております。
Posted at https://sl.advdat.com/3ldVNby